org-special-block-extras: demos that are tests, rather than docs

(org-make-badge "badge")

(org-deflink kbd (keys &optional description backend)
  "Show keysequence KEYS in a nice grey button-like font, along with a tooltip of its documentation, if any.

Such links do not get folded in [[bracket]] style, and are rendered as buttons within Emacs; clicking one
runs its keys, so readers may try them out.  Keys may run any command, so we first ask, as `elisp' links
do, via `org-link-elisp-confirm-function'.

Moreover, KEYS may use ‘_’ in-lieu of spaces or [[bracket]] link notation.

Examples:
    [[kbd:C-x C-s]]
  ≈ <kbd: C-x C-s>
  ≈ kbd:C-x_C-s"
  :display 'full
  :manual "#nice-keystroke-renditions"
  :let (the-label  (s-trim (s-replace "_" " " keys))
        lisp-func  (ignore-errors (key-binding (kbd the-label)))
        tooltip    (or description (ignore-errors (documentation lisp-func)) "")
        tooltip?   (not (equal tooltip ""))
        style      (if tooltip? "border-color: red" "")
        keystrokes (progn (org-html-head-require 'org--kbd-html-head)
                          (format "<kbd style=\"%s\">%s</kbd>" style the-label)))
  ;; The description is always nil when it comes to deciding the :face.
  :face (list :inherit 'custom-button :box (if tooltip? "red" t))
  :help-echo (format "%s ∷ %s\n%s\n\nClick to run these keys." the-label (or lisp-func "") tooltip)
  :follow (org--kbd-run the-label)
  :export (cond ((equal backend 'latex) (format "\\texttt{%s}" the-label))
                ;; The style is to remove the underlining caused by <abbr>.
                (tooltip? (org--html-tooltip (format "%s ∷ %s\n%s" the-label (or lisp-func "") tooltip) keystrokes
                                             :plain "border: none; text-decoration: none;"))
                (t keystrokes)))

(org-defblock solution
              (&optional (title "Solution")
               &key (reprimand "Did you actually try? Maybe see the ‘hints’ above!") (really "Solution, for real")
               &allow-other-keys :manual "#Boxed-Text" &context raw-contents)
              "Show the answers to a problem, but with a reprimand in case no attempt was made."
              (org-thread-blockcall raw-contents
                                    (details really :title-color "red")
                                    (box reprimand :background-color "blue")
                                    (details title)))

(org-defblock spoiler (&optional (color "grey") &key (left "((") (right "))") &allow-other-keys :manual "#Boxed-Text"
                      &context backend raw-contents contents)
              "Hide text enclosed in double parens ((like this)) as if it were spoilers.
   LEFT and RIGHT may be other kinds of delimiters.
   The main argument, COLOR, indicates which color to use.

For LaTeX, this becomes “fill in the blanks”, with the answers
in the footnotes; for Markdown, whose renderers strip <style>, numbered
blanks with the answers folded away beneath them."
              (cond
               ((org-export-markdown-p)
                (let* ((answers nil)
                       (blanked (replace-regexp-in-string
                                 (concat (regexp-quote left) "\\(.*?\\)" (regexp-quote right))
                                 (lambda (it)
                                   (push (match-string 1 it) answers)
                                   (format "@@html:<ins>&emsp;%s&emsp;</ins>@@" (length answers)))
                                 raw-contents t t)))
                  (org-parse (format "%s\n\n#+html: <details><summary>Answers</summary>\n\n%s\n\n#+html: </details>"
                                     blanked
                                     (s-join "\n" (--map-indexed (format "%s. %s" (1+ it-index) it) (reverse answers)))))))
               ((equal backend 'latex)
                (s-replace-regexp
                 (concat (regexp-quote left) "\\(.*?\\)" (regexp-quote right))
                 "@@latex:\\\\fbox{\\\\phantom{\\1}}\\\\footnote{\\1}@@"
                 contents))
               (t
                ;; The styling depends only on COLOR, so a class per colour serves every spoiler of that colour.
                (-let [class (format "spoiler-%s" color)]
                  (concat
                   ;; In HTML, a ‘style’ can be, technically, almost anywhere...
                   (format "<style> .%s {color: %s; background-color:%s;} .%s:hover {color: black; background-color:white;} </style>\n"
                           class color color class)
                   (s-replace-regexp
                    (concat (regexp-quote left) "\\(.*?\\)" (regexp-quote right))
                    (format "@@html:<span class=\"%s\"> \\1 </span>@@" class)
                    contents))))))

(org-defblock tree (&allow-other-keys :html-head (mathjax) :manual "#Aligned-equations" &context raw-contents)
              "Write a proof tree using Org-lists.

To get

         premises₀  …   premisesₙ
       ────────────────────────────[ reason ]
               conclusion

You type

       #+begin_tree
       + reason :: conclusion
         - premises₀
         - premises₁
         ⋮
         - premisesₙ
       #+end_tree

Where each premisesᵢ may, recursively, also have named reasons
and (indented) child premises of its own.

If there are multiple trees, they are shown one after the other.

The text in this block should be considered LaTeX;
as such, Org markup is not recognised.

A proof tree, derivation, is then just a deeply nested
itemisation.  For instance, assuming P = Q(X), X = Y, Q(Y) = R,
the following proves P = R.

  #+begin_tree
  + Trans :: P = R
    - P = Q(X)
      + ✓
    - Trans :: Q(X) = R
      + Trans :: Q(X) = Q(Y)
        - Refl :: Q(X) = Q(X)
          + ✓
        - Leibniz :: Q(X) = Q(Y)
          + X = Y
            - ✓
      + Sym :: Q(Y) = R
        - R = Q(Y)
          - ✓
  #+end_tree

In Markdown, each tree is a $$…$$ display, since GitHub's maths knows no \\[…\\]."
              (-let [md? (org-export-markdown-p)]
                (mapconcat (lambda (it) (format (if md? "$$%s$$" "\\[%s\\]") (org--list-to-math it)))
                           (cdr (org--parse-plain-list raw-contents "tree"))
                           (if md? "\n\n" ""))))